Gleiches Verzeichnis auf unterschiedl. Laufwerken wechseln

[RobbyKnownAsWick]

Hallo zusammen!

Würde gerne per Button z.B. im Linken Fenster auf das Verzeichnis des rechten Fensters jedoch auf einem anderen Laufwerk wechseln.

z.B.:

Links: C:\Programme\totalcmd
Rechts: X:\Temp
-> Click auf Button
Rechts: X:\Programme\totalcmd

Wie geht das?
Grüße
Robby

[van Dusen]

Du könntest z.B. dieses Script per Button aufrufen:

Code: Select all

;*** MatchTrgEqSrc.au3 V0.1, 15.09.2006
#cs
Script für AutoIt V3.2.0.1 (http://www.autoitscript.com/autoit3/)
Zur Verwendung mit TotalCommander (http://www.ghisler.com)
Setzt das Verzeichnis im Ziel-Panel auf das Verzeichnis des Quell-Panels unter Beibehaltung des Laufwerksbuchstabens
Bsp.: Q = C:\hierhin\willich; Z = D:\ganz\woanders -- *Script* --> Q = C:\hierhin\willich; Z = D:\hierhin\willich
#ce

AutoItSetOption("WinTitleMatchMode", 4)
$strTCexe = "C:\Programme\TotalCmd\TotalCmd.exe"

_TCPostMessage(2029) ;*** cm_CopySrcPathToClip=2029;Copy source path to clipboard
$strSrcDir = ClipGet()
If StringInStr($strSrcDir, ":") = 0 Then _
	_ErrMsg($strSrcDir & @LF & "UNC-Pfade werden von diesem Script nicht unterstützt, sorry!")

_TCPostMessage(2030) ;*** cm_CopyTrgPathToClip=2030;Copy target path to clipboard
$strTrgDir = ClipGet()
If StringInStr($strTrgDir, ":") = 0 Then _
	_ErrMsg($strTrgDir & @LF & "UNC-Pfade werden von diesem Script nicht unterstützt, sorry!")

$strTrgDir = StringLeft($strTrgDir, 2) & StringMid($strSrcDir, 3)

If Not FileExists($strTrgDir) Then _
	_ErrMsg("Der Pfad" & @LF & $strTrgDir & @LF & "existiert nicht!")

Run($strTCexe & " /O /S /R=" & Chr(34) & $strTrgDir & Chr(34))

;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Func _TCPostMessage($msg)
	DllCall("user32.dll", "int", "PostMessage", "hwnd", WinGetHandle("classname=TTOTAL_CMD"), "int", 1075, "int", $msg)
	Sleep(100)
EndFunc

;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Func _ErrMsg($strErrMsg)
	MsgBox(64, @ScriptName, $strErrMsg)
	Exit 1
EndFunc

In der Zeile
$strTCexe = "C:\Programme\TotalCmd\TotalCmd.exe"
müsstest Du erst noch den Dateipfad zum TotalCommander anpassen

[Hacker]

Oder auch dieses AutoHotkey Skript:

Code: Select all

#NoEnv
ControlGetText, Path, TMyPanel2, A
StringReplace, Path, Path, >, \
StringMid, Path, Path, 3
Send, {Tab}
PostMessage, 1075, 4003
SendInput, {Raw}cd %Path%
Send, {Enter}{Tab}

Roman