Inhaltsplugin für besondere Dateiformate

[Tarnkappe]

Hallo,

ich bin auf der Suche nach einem Inhaltsplugins, das beispielsweise folgendes leistet:

Zeige aus allen Datei in einem Verzeichnis aus der 3. Zeile das 4-6 Zeichen in der Dateiliste an.

Gibt es sowas schon? Oder kann das der TC vielleicht sogar ohne Plugin?

Danke und Gruß,
die Tarnkappe

[van Dusen]

Der TC leistet das mit Bordmitteln nicht. Ein Inhaltsplugin ist mir auch nicht bekannt (es gibt zwar ein Plugin namens <FileContent.wdx> mit der Beschreibung "FileContent kann benutzt werden um Dateiinhalte nach Text zu durchsuchen." in der <pluginst.inf>... eine ausführlichere Doku zum Plugin liegt mir aber leider nicht vor).

Du könntest aber das script content plugin i.V.m. folgendem (Beispiel-)Script verwenden und nach deinen Bedürfnissen anpassen:

Code: Select all

'*** ExtractText.vbs, van Dusen, 30.05.2007
'*** Script for Script Content Plugin
'*** (c)Lev Freidin, 2005
'*** http://www.totalcmd.net/plugring/script_wdx.html
'*** http://wincmd.ru/plugring/script_wdx.html

On Error Resume Next

vResult = ""
vMode = "ABS"

'*** vMode = "ABS":
'*** Für die Rückgabe des Texts an fester Position (Zeile, Spalte von/bis)
vLineWanted = 3
vColFrom = 4
vColTo = 6

'*** vMode = "REL":
'*** Für die Rückgabe des auf ein Schlüsselwort (vSearchFor) folgenden Texts
vSearchFor = "[Text]"
vStartPosOffset = 2

Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
sExt = lcase(oFSO.GetExtensionName(filename))

'*** Dateitypen, die ausgewertet werden sollen, einschränken...
If Instr("txt|erg|log|wrl|vbs|js|au3", sExt) > 0 Then
	Set f = oFSO.OpenTextFile(filename, 1, False)

   If vMode = "ABS" Then
      For vLineCurrent = 1 To vLineWanted - 1
         f.SkipLine
      Next
      vContent = f.ReadLine
      vResult = Mid(vContent, vColFrom, vColTo - vColFrom + 1)
   End If
	
   If vMode = "REL" Then
      vContent = f.ReadAll
	   vStartPos = Instr(vContent, vSearchFor)
	   If vStartPos > 0 Then
         vStartPos = vStartPos + Len(vSearchFor) + vStartPosOffset
         vResult = Mid(vContent, vStartPos)
      End If
   End If

End If

f.Close
Set oFSO = Nothing
Set f = Nothing

content = vResult

Grüße, van Dusen

[Tarnkappe]

Vielen Dank!
Das sieht sehr vielversprechend aus. Werde ich so bald wie möglich mal ausprobieren!