AutoHotkey: Send a command to Total Commander

The purpose of this script is to send an internal command to Total Commander (e.g. from a batch file). Useful to collect some tasks to automate them for usage with a Button.

A compiled version of this script is here available. (This is a free webhoster, thus the file has to be activated from time to time. So in case the file is not available anymore, please send a short mail to sheepdog at gmx dot net with subject Total Commander.)

; Script name: SendTCCommand.ahk

; Sends a Total Commander command to a TC instance.
; Can be used from the scheduler for example.

; Specify the TC command as command line parameter for example:
;   AutoHotkey.exe SendTCCommand.ahk cm_FtpNew
; Or if the script is compiled:
;   SendTCCommand.exe cm_FtpNew

sCmdParam = %1%
SendTCCommand( sCmdParam )
Return

;
; SendTCCommand 0.1
;
; Function purpose:
;    Sends a Total Commander internal command to a TC instance.
;    It can be used to automate Total Commander.
;
; Parameters:
;    xsTCCommand: The Total Commander internal command, see the list here:
;                 %COMMANDER_PATH%\TOTALCMD.INC
;
; Usage example:
;	SendTCCommand( "cm_RereadSource" )
;

SendTCCommand( xsTCCommand )
{
	loop Read, %COMMANDER_PATH%\TOTALCMD.INC
	{
		StringSplit asCommands, A_LoopReadLine, =
		if (asCommands1 = xsTCCommand)
		{
			StringSplit asCommandsValues, asCommands2, `;
			Break
		}
	}

	if (asCommandsValues1 > 0)
		PostMessage 1075, %asCommandsValues1%, 0, , ahk_class TTOTAL_CMD
}

Back to AutoHotkey